package
{
	import flash.events.Event;
	import flash.events.EventDispatcher;
	import flash.events.NetStatusEvent;
	import flash.events.StatusEvent;
	import flash.net.GroupSpecifier;
	import flash.net.NetConnection;
	import flash.net.NetGroup;
	import flash.net.NetGroupReplicationStrategy;
	import flash.utils.ByteArray;

	
	[Event(name="complete",type="flash.events.Event")]
	[Event(name="status",type="flash.events.StatusEvent")]
	public class P2PFileShare extends EventDispatcher
	{
		
		[Bindable]
		public var connected:Boolean = false;
		
		public var netConnection:NetConnection;
		
		[Bindable]
		public var netGroup:NetGroup;
		
		private const SERVER:String = "rtmfp://stratus.adobe.com/";
		private const DEVKEY:String = "YOUR-DEV-KEY";
		
		public var p2pSharedObject:P2PSharedObject;
		
		public function P2PFileShare()
		{
		}
		
		public function connect():void{
			netConnection = new NetConnection();
			netConnection.addEventListener(NetStatusEvent.NET_STATUS,netStatus);				
			netConnection.connect(SERVER+DEVKEY);
		}
		
		public function startSharing(p2pSharedObject:P2PSharedObject):void{
			writeText("startSharing - chunks shared: "+p2pSharedObject.packetLenght);
			
			this.p2pSharedObject = p2pSharedObject;
			
			netGroup.addHaveObjects(0,p2pSharedObject.packetLenght);
		}
		
		public function startReceiving():void{
			writeText("startReceiving");
			
			p2pSharedObject = new P2PSharedObject();
			p2pSharedObject.chunks = new Object();
			
			receiveObject(0);
		}
		
		
		protected function onGroupConnected():void{
			netGroup.replicationStrategy = NetGroupReplicationStrategy.LOWEST_FIRST;
			
		}
		
		protected function netStatus(event:NetStatusEvent):void{
			writeText(event.info.code);
			
			switch(event.info.code){
				case "NetConnection.Connect.Success":
					setupGroup();
					break;
				
				case "NetGroup.Connect.Success":
					connected = true;
					
					onGroupConnected();
					
					break;
				
				case "NetGroup.Replication.Fetch.SendNotify": // e.info.index
					writeText("____ index: "+event.info.index);
					
					break;
				
				case "NetGroup.Replication.Fetch.Failed": // e.info.index
					writeText("____ index: "+event.info.index);
					
					break;
				
				case "NetGroup.Replication.Fetch.Result": // e.info.index, e.info.object
					//writeText("____ index: "+event.info.index+" | object: "+event.info.object);
					
					netGroup.addHaveObjects(event.info.index,event.info.index);
					
					p2pSharedObject.chunks[event.info.index] = event.info.object;
					
					if(event.info.index == 0){
						p2pSharedObject.packetLenght = Number(event.info.object);
						writeText("p2pSharedObject.packetLenght: "+p2pSharedObject.packetLenght);
						
						receiveObject(1);
						
					}else{
						if(event.info.index+1<p2pSharedObject.packetLenght){
							receiveObject(event.info.index+1);
						}else{
							writeText("Receiving DONE");
							writeText("p2pSharedObject.packetLenght: "+p2pSharedObject.packetLenght);
							
							p2pSharedObject.data = new ByteArray();
							for(var i:int = 1;i<p2pSharedObject.packetLenght;i++){
								p2pSharedObject.data.writeBytes(p2pSharedObject.chunks[i]);
							}
							
							writeText("p2pSharedObject.data.bytesAvailable: "+p2pSharedObject.data.bytesAvailable);
							writeText("p2pSharedObject.data.length: "+p2pSharedObject.data.length);
							
							dispatchEvent(new Event(Event.COMPLETE));
						}
					}
					
					
					break;
				
				case "NetGroup.Replication.Request": // e.info.index, e.info.requestID
					netGroup.writeRequestedObject(event.info.requestID,p2pSharedObject.chunks[event.info.index])
					//
					
					writeText("____ ID: "+event.info.requestID+", index: "+event.info.index);
					break;
				
				default:
					break;
			}
		}
		
		protected function setupGroup():void{
			writeText("setupGroup");
			
			var spec:GroupSpecifier = new GroupSpecifier("myGroup");
			spec.serverChannelEnabled = true;
			spec.objectReplicationEnabled = true;
			
			
			netGroup = new NetGroup(netConnection,spec.groupspecWithAuthorizations());
			netGroup.addEventListener(NetStatusEvent.NET_STATUS,netStatus);
			
		}
		
		
		protected function receiveObject(index:Number):void{
			netGroup.addWantObjects(index,index);
			p2pSharedObject.actualFetchIndex = index;
		}
		
		protected function writeText(str:String):void{
			var e:StatusEvent = new StatusEvent(StatusEvent.STATUS,false,false,"status",str);
			
			dispatchEvent(e);
		}
		
		
		
	}
}